/*
	Led RGB e Display LCD : HSB loop
 
	Makes an RGB led to loop on all colors and displays
	the RGB values into an LCD display. The color loop
	is achieved varying the Hue value from 0 to 255 and
	converting the HSB value into RGB values.
 
	The circuit:
		* LCD RS pin to digital pin 13
		* LCD Enable pin to digital pin 12
		* LCD D4 pin to digital pin 5
		* LCD D5 pin to digital pin 4
		* LCD D6 pin to digital pin 3
		* LCD D7 pin to digital pin 2
		* 10K resistor:
		* ends to +5V and ground
		* wiper to LCD VO pin (pin 3)
 
		* RGB Led Red pin to PWM pin 9
		* RGB Led Green pin to PWM pin 10
		* RGB Led Blue pin to PWM pin 11
		* RGB Led GND pin to GND
		* 220 resistors:
		* on each led's color pin
 
	Based on the Arduino Liquid Crystal tutorial and
	the HSBtoRGB function from Paul V. (Arduino Forum).
		* http://www.arduino.cc/en/Tutorial/LiquidCrystal
		* http://www.arduino.cc/cgi-bin/yabb2/YaBB.pl?num=1235225449/13#13
 
	By Manoel Lemos
	http://manoellemos.com/category/arduino
*/
 
// include the library code:
#include 
 
// initialize the library with the numbers of the interface pins
LiquidCrystal lcd(13, 12, 5, 4, 3, 2);
 
int rPin = 9;    // Led Red pin connected to PWM pin 9
int gPin = 10;   // Led Green pin connected to PWM pin 10
int bPin = 11;   // Led Blue pin connected to PWM pin 11
unsigned int r, g, b; // RGB values from the HSBtoRGB function
char rS[5], gS[5], bS[5], hS[5]; // RGB & Hue values as strings
int hue; // Hue value
 
void setup() {
	// set up the Arduino pins as PWM
	pinMode(gPin, OUTPUT);
	pinMode(bPin, OUTPUT);
 
	// set up the LCD's number of rows and columns:
	lcd.begin(16, 2);
}
 
void loop() {
	for(int hue = 0; hue <= 255; hue = hue + 4){
 
		// calculate the RGB values for the current Hue value
		HSBToRGB( hue, 255, 255, &r, &g, &b ); 
 
		// set the RGB Led to the calculated RGB values
		analogWrite(rPin, r);
		analogWrite(gPin, g);
		analogWrite(bPin, b);
 
		// convert the RGB and Hue values to strings
		itoa(hue,hS,10);
		itoa((int) r, rS, 10);
		itoa((int) g, gS, 10);
		itoa((int) b, bS, 10);
 
		// print the data on the display
		lcd.setCursor(0,0);
		lcd.print("Hue: ");
		lcd.print(hS);
		lcd.print("               ");
		lcd.setCursor(0,1);
		lcd.print("RGB: ");
		lcd.print(rS);
		lcd.print(",");
		lcd.print(gS);
		lcd.print(",");
		lcd.print(bS);
		lcd.print("          ");
 
		// wait
		delay(50);
	}
}
 
void HSBToRGB( unsigned int inHue, unsigned int inSaturation, unsigned int inBrightness, unsigned int *oR, unsigned int *oG, unsigned int *oB )
{
	if( inSaturation == 0 )
	{
		// achromatic (grey)
		*oR = *oG = *oB = inBrightness;
	}
	else
	{
		unsigned int scaledHue = (inHue * 6);
		unsigned int sector = scaledHue >> 8; // sector 0 to 5 around the color wheel
		unsigned int offsetInSector = scaledHue - (sector << 8);	// position within the sector
		unsigned int p = (inBrightness * ( 255 - inSaturation )) >> 8;
		unsigned int q = (inBrightness * ( 255 - ((inSaturation * offsetInSector) >> 8) )) >> 8;
		unsigned int t = (inBrightness * ( 255 - ((inSaturation * ( 255 - offsetInSector )) >> 8) )) >> 8;
 
		switch( sector ) {
			case 0:
				*oR = inBrightness;
				*oG = t;
				*oB = p;
			break;
			case 1:
				*oR = q;
				*oG = inBrightness;
				*oB = p;
			break;
			case 2:
				*oR = p;
				*oG = inBrightness;
				*oB = t;
			break;
			case 3:
				*oR = p;
				*oG = q;
				*oB = inBrightness;
			break;
			case 4:
				*oR = t;
				*oG = p;
				*oB = inBrightness;
			break;
			default:		// case 5:
				*oR = inBrightness;
				*oG = p;
				*oB = q;
			break;
		}
	}
}